Hojas de cálculo en Excel - página principal

Tiempo transcurrido entre dos fechas

En el siguiente ejemplo, vamos a calcular el tiempo transcurrido entre dos fechas, evaluando los años, meses, y días transcurridos. Una de esas fechas, supondremos que corresponde a la fecha de hoy. La otra fecha será la fecha de nacimiento de una serie de personas. Vamos a calcular el tiempo transcurrido desde el día de su nacimiento, hasta hoy.

Para ello, fijaos en esta imagen (doble clic para ampliarla, si no veis bien los detalles):


Antes de nada, comentaros que el texto "años", "meses", y "días", que se muestra en las celdas C5, D5 y E5 lo podríamos haber puesto de muchas formas distintas, pero he optado por hacerlo dándole formato a las celdas, desde Formato, Celdas…, y en la pestaña Número, dentro de la categoría Personalizada, poniendo para el caso de C5, esto que aparece en la imagen (en el caso de D5 y E5 será similar, pero poniendo texto "meses", "días", y "años"):


Si os fijáis, en la celda C5 de la primera imagen, es donde evaluamos los años transcurridos. Tenemos esta fórmula:


=SIFECHA(B5;C$2;"y")

El símbolo del $ nos indica que estamos trabajando con una referencia absoluta, así podremos copiar esa fórmula de C5 en las celdas que hay por debajo, sin necesidad de tener que cambiar ningún dato de la misma. Pues bien, si os fijáis, estamos utilizando la función SIFECHA, que consta de tres partes. La primera de ellas corresponde a la fecha final (la fecha más actual), la segunda corresponde a la fecha inicial (la fecha más antigua), y la tercera parte, la más importante, corresponde al periodo a evaluar, en este caso los años transcurridos (en números enteros), por eso utilizamos "y" (y = years, es decir, años). Es decir, esa fórmula nos está informando del número de años enteros que han transcurrido entre esas dos fechas.

En la celda D5, donde evaluamos los meses transcurridos, tenemos algo parecido:

=SIFECHA(B5;C$2;"ym")

Si os fijáis, esta fórmula, se diferencia de la anterior en el tercer término, donde ahora aparece "ym". Esta parte nos viene a decir que queremos mostrar los meses (también en números enteros) m (m = months, es decir, meses) que pasen de los años enteros y. Si en lugar de poner en ese tercer término ym, hubiésemos puesto m, habríamos obtenido 478 meses, en lugar de 10. La razón es muy sencilla: con m obtenemos los meses transcurridos desde esas dos fechas (la inicial y la final), mientras que con ym solo obtenemos aquellos meses que han transcurrido desde el último año entero (en este caso, 39), y que todavía no llegan para formar otro año, es decir, no llegan a 12 meses.

En la celda E5, tenemos esta función, donde evaluaremos los días transcurridos:

=SIFECHA(B5;C$2;"md")

En este caso, el md del tercer término nos informa de que queremos obtener los días que hayan transcurrido desde el último mes entero. Como en el ejemplo de E5, no llegamos a obtener 11 meses (son 10 meses y pico como véis en la tabla, y precisamente lo que deseamos obtener ese "pico"). Si hubiésemos puesto d, en lugar de md, habríamos obtenido 14.562 días, en lugar de los 13 días que hemos obtenido. La razón es similar al caso anterior de los meses. Utilizando d (d = days, es decir, días), estamos obteniendo la diferencia en días entre la fecha inicial y final. Con md solo mostramos los días d que han transcurrido desde el último mes entero m (desde el mes 10, en adelante).

Si deseamos unir esos tres datos, en una sola celda, podemos concatenarlos (unirlos) con el operador &, al que le añadiremos entre comillas, un texto que informará de si son años, meses, o días. Por ejemplo, en F5 tenemos esta fórmula (debéis ponerla toda en una línea, aunque yo la he puesto en dos para que no se descoloque en pantalla):

=SIFECHA(B5;C$2;"y") & " años " & SIFECHA(B5;C$2;"ym") &
" meses " & SIFECHA(B5;C$2;"md") & " días"

Para calcular la diferencia entre dos fechas, podemos utilizar las siguientes opciones:

=SIFECHA(fecha_final;fecha_inicial;"y")
=SIFECHA(fecha_final;fecha_inicial;"m")
=SIFECHA(fecha_final;fecha_inicial;"d")
=SIFECHA(fecha_final;fecha_inicial;"ym")
=SIFECHA(fecha_final;fecha_inicial;"yd")
=SIFECHA(fecha_final;fecha_inicial;"md")

Cuando en el tercer término utilizamos dos elementos, siempre el primero de ellos debe ser mayor que el segundo, de ahí que pongamos ym, yd, o md. Si utilizamos dm, my, dy, nos dará error por motivos obvios (de igual forma que solo podemos meter un recipiente pequeño en uno grande, y no al revés). En el caso de utilizar ym, estaremos obteniendo el número de días que hayan transcurrido desde el último año entero. Siempre obtendremos por tanto, 364 días (o 365, si estamos hablando de un año bisiesto) como máximo, ya que en cuanto pasemos 1 día de esas dos cifras, ya tendremos un nuevo año entero.

Desde aquí podéis descargar el fichero de Excel, con el ejemplo que hemos visto en este artículo.



128 comentarios:

Ernesto Gremoliche dijo...

Excelente! muchas gracias!

Javier Marco dijo...

De nada :-)

Anónimo dijo...

Gracias!!, hacia tiempo venia rompiendome la cabeza para poder calcular esto!!!

Javier Marco dijo...

De nada. Como ves no es tan complicado como podría parecer en un principio.

Gracias por tu comentario :-)

Anónimo dijo...

Lo ke estaba buscando... jajajaja, muchas gracias por tu aporte

Javier Marco dijo...

Muchas gracias por tu comentario. Me alegro que te haya sido útil.

Salu2

jrgmontero dijo...

Me ha sido de mucha utilidad. Una entrada clara y concisa, bien explicado. Gracias

Javier Marco dijo...

Muchas gracias por tu comentario.

Salu2

Anónimo dijo...

Muy buena explicación. Excelente y muy clara. Me viene muy bien porque en mi trabajo estamos calculando antigüedad docente que nuestros empleados tenía de otros lugares y la verdad me viene de mil maravillas ésto !!
Gracias y saludos.
Mariano (Bs. As. - Argentina)

Javier Marco dijo...

Gracias por tu comentario.

Me alegro que te haya servido.

victor dijo...

hola tu explicacion me parece excelente y muy util, pero hace poco encontre una formula que hacia esta expresion de antiguedad en años meses y dias sin tanto calculo, pero tontamente no la guarde y no he podido encontrar la pagina de donde la copie, crees que la pudieras encontrar?

Valedor dijo...

no tengo la función SIFECHA() EN EXCEL, DE DONDE LA INSTALO?
GRACIAS

Javier Marco dijo...

Debería estar incluida en la propia aplicación de excel. Quizás lo que no tengas sea la ayuda (en Excel XP no viene la ayuda para esa función).

O quizás tengas la versión inglesa de excel y debas buscarla por DATEIF, en lugar de SIFECHA.

Un saludo.

Anónimo dijo...

Muy Bueno me gustaria que me explicara si hay una forma de hacer esta funcion en forma de macro, es para una tarea debo hacer una constancia de años de trabajo en excel y enviar datos a word todo esto usando macros ¿Se podra????? Gracias

Anónimo dijo...

BUENAZA LA FORMULA EXCELENTE, muy buen aporte

Javier Marco dijo...

Muchas gracias por tu comentario :-)

Anónimo dijo...

Gracias esta arrechisisima....la estaba buscando..felicitaciones.

Javier Marco dijo...

Muchas gracias por tu comentario.

Koni dijo...

Brillante...el que sabe sabe...agradecido...!!

Javier Marco dijo...

Muchas gracias por tu comentario.

Anónimo dijo...

hola, es fantastico y todo un logro, pero una cosita más, ¿se podría calcular lo mismo pero con meses de 30 dias, o lo que es lo mismo, años de 360 dias? Gracias

Javier Marco dijo...

A pesar de que existe la función DIAS360(fecha inicial; fecha final), como la función SIFECHA es nativa de excel, no podremos "manipular" el cálculo para decirle "ehh, los años que sean de 360 días". No podemos porque los años los controla directamente excel a través de la función SIFECHA.

Otra cosa es que puedas hacer algo con la función DIAS360, que te devolverá la diferencia en días entre 2 fechas, contando los meses como si fuesen de 30 días, pero ya no será una función que te devuelva años, meses y días transcurridos, sino solo días.

Puedes usar la ayuda de excel (pulsa F1), para ver más sobre la función DIAS360.

Anónimo dijo...

Muchas gracias Javier Marco. Soy el anonimo de DIAS360

Anónimo dijo...

Buenos dias, tengo otra duda, ¿como puedo pasar el resultado de sumar tres celdas (dá el numero de dias entre tres fechas)a meses y dias?. Por ejemplo si el resultado fuera "44" en otra casilla pondria 1 mes 14 dás. soy el anonimo de DIAS360. GRACIAS.

Javier Marco dijo...

Suponiendo que en la celda A1 tengas ese dato (44). Pon esto en B1:

=ENTERO(A1/30)

Y esto otro en C1:

=A1-(ENTERO(A1/30)*30)

Si lo quieres todo en una sola celda, pon esto en D1:

=ENTERO(A1/30)&" mes(es) "&A1-(ENTERO(A1/30)*30)&" día(s)"

De nada :-)

Anónimo dijo...

Muchas gracias Javier Marco!!, mira que he mirado cosas eh...,. Me has ayudado mucho. Hasta otra. El anonimo D360

Javier Marco dijo...

Gracias por tu comentario :-)

Anónimo dijo...

he probado esta formula en excel 2007 y en openoffice y a mi personalmente no me funciona, no se qué hago mal pero no me sale.
Yo en concreto necesito esta fórmula para el calculo de indemnizaciones de despido, he encontrado en openoffice la formula FRAC.AÑO calcula el tiempo transcurrido entre dos fechas, en fracciones de año
Quisiera saber tu opinión
gracias por adelantado

Javier Marco dijo...

La verdad es que no soy usuario de openoffice, y no te puedo ayudar. Respecto a Excel 2007, comprueba que no tengas la versión inglesa, y que por tanto debas cambiar la fórmula SIFECHA por DATEDIF. Si tienes la versión en español, debería funcionarte tal y como está explicado en el artículo.

Saludos.

Anónimo dijo...

hola: queria saber si podrias ayudarme... no recuerdo cual es la formula para calcular los dias transcurridos entre una fecha de ingreso ala fecha actual. probe con las q hay y no me da resultado. grax

Javier Marco dijo...

Si te lees bien el artículo, y pones las funciones como se deben poner, no tendrías que tener ningún tipo de problemas, porque funcionan perfectamente. Pruébalo de nuevo, y verás como lo solucionas rápidamente.

Un saludo.

Anónimo dijo...

Hola a todos desde Mexico, tenia el problema y me marcaba error, y lo solucione cambiando en la formula los signos ;(punto y coma) como aqui lo indican por ,(coma) y quedo resuelto y listo para entregar el reporte

Anónimo dijo...

es estupendo me ha ahorrado un gran trabajo

Javier Marco dijo...

Me alegro que os haya servido :-)

Anónimo dijo...

Si en tu ejemplo necesitara sumar las celdas F5:F10 ¿cómo tendría que hacerlo para que lo hiciera correctamente y me apareciera en el formato años-meses-días?

Anónimo dijo...

Increíble y utilísima tu aportación. Muchas gracias.

Anónimo dijo...

Hola a todos, no se si será aquí en esta página,y es que tengo un problema con una tabla en ACCESS, y es que pongo un número "001" y me quita los ceros, es importante que los ceros se queden, me gustaría saber si o bien en opciones o con el editor se podría solucionar. Gracias anticipadas.

Anónimo dijo...

Hola, soy el anonimo del 001, el de "access", solucionado, me dí cuenta justo despues de enviar el comentario; pero por si acaso, la solucion es poner dicho campo con formato "texto". De cualquier forma muchas garcias.

Anónimo dijo...

Excelente, practico y muy didactico

Victor dijo...

quisiera que me audaras con lo siguiente:

cada mes niesito agregar un valor fijo una celda predeterminada, es decir un una celda 01/05/09 = 13(en otra celda), 01/06/09 = 14.25

Esto lo necesit para llever un cotrol de vacaciones que necesito entregar mensualmnte

Victor dijo...

Creo que en el mensaje anterior no me pude explicar bien.

Lo que necesito es sumarle 1.25 días a cada mes que va pasando a partir de la fecha de ingreso del trabajador a la empresa, es decir si tengo una persona que ingresó el 01 de enero de 2009, quisiera saber si existe una fórmula que automáticamente al llegar al 01 de febrero de 2009 esta persona aparezca con 1.25 días de vacaciones en la celda siguiente, al llegar al 01 de marzo aparezca en la misma celda que ya tiene 2.50 días de vacaciones y así durante todo el año.

El motivo por el que necesito saber si hay una fórmula que pueda sumar ese “1.25” cada mes es porque tengo 500 empleados a los que les tengo que hacer el cálculo manual mensualmente y realmente es algo que me quita mucho tiempo y quisiera ver si hay alguna forma de poder hacerlo con una formula.

Anónimo dijo...

Gracias!!!!!!!! Justo lo que buscaba

Marcos dijo...

Hola, soy Marcos, muchisimas gracias por compartir tus enseñanzas, estan muy buenas e interesantes, vale la pena leerlas, eres un profesional de excel, jejeje, una herramienta muy importante hoy en día. Saludos desde Uruguay

Anónimo dijo...

Diana dijo...

No tengo la funcion SIFECHA, como la puedo conseguir, yo tengo excel 2003.

por favor necesito saberlo... espero respuesta bye...

Javier Marco dijo...

Una cosa es que no esté documentada la función SIFECHA en Excel 2003, y otra que no exista.

Yo utilizo Excel 2003, y me funciona perfectamente la función SIFECHA.

Anónimo dijo...

Me ha gustado mucho el blog y esta entrada también la he encontrado muy práctica para mi trabajo porque en muchas ocasiones necesitos contar lso días de contrato de lso trabajadores pero he detectado que siempre quita un día.
Por ejemplo si un trabajador tuvo contrato de 01/01/2009 al 01/02/2009 el programa arroja un resultado de un mes cuando lo correcto es un mes y un día.
¿alguien sabe si se pueden adaptar las fórmulas para que tenga en cuenta ese detalle? Y si las respuesta es afirmativa, ¿cómo?

Javier Marco dijo...

Piensa que estamos haciendo una resta entre días, y de la misma forma en que 3 - 1 = 2, aquí la diferencia entre fechas, es exactamente igual.

Lo que quieres hacer es tan sencillo como añadirle 1 a la diferencia entre esas dos fechas, para que sume también el día de incoporación del trabajador, y así computar también ese día.

Por ejemplo, añade a la fórmula que concatena años, meses, y días, ese +1, de tal forma que te quede así (imagina que en B4 tienes puesta la fecha de hoy, y en B5 una fecha anterior):

=SIFECHA(B5;B$4;"y") & " años " & SIFECHA(B5;B$4;"ym") & " meses " & SIFECHA(B5;B$4;"md")+1 & " días"

Con eso tienes solucionado el problema.

Un saludo.

Randall dijo...

Esta perfecto, esto es justo lo que necesitaba, muchas gracias por expresar tu conocimiento.

Anónimo dijo...

La Formula excelente. Quiero saber si excel puede convertir una fecha en numero y como se hace. Por ejemplo La fecha 25/01/2008 convertirla en el numero 125 - 8
Para esto excel debe dividir el año en bimiestre. Ejm.
Ene - Feb Bimestre 1
Mar - Abr Bimestre 2
May - Jun Bimestre 3
Jul - Ago Bimestre 4
Sep - Oct Bimestre 5
Nov - Dic Bimestre 6
El numero 125 - se forma así: El Uno. Es el numero del bimestre al que pertenece el Mes, como enero pertenece al primer bimestre le corresponde el Uno. El Veinticinco son los 25 dias de enero y el 8 es el año de la fecha.
Otro Ejemplo. 28/12/2009 el numero que debe dar la formula es 658 - 9
Se obtiene así: El mes es dic corresponde al bimestre 6. El 58 se obtine de los 30 dias de Nov mas los 28 dias de Dic y el nueve es el año de la fecha. Esto lo necesito para enumerar el ganado teniendo en cuenta la fecha de nacimiento, y tener un control absoluto sobre los animales.
De antemano le agradezco todo lo que pueda hacer por mi. Atte, Eder Monterroza Montiel. Cartagena Colombia

Javier Marco dijo...

Hola Eder. Preguntáis cada cosa, que alucino...

Para que te funcione la fórmula que te propongo más abajo, comprueba que tengas activadas las herramientas para análisis (ahora mismo tengo delante la versión Excel 2003, así que te digo donde se encuentra en Excel 2003: Menú Herramientas --> Complementos ---> Debes tener marcada la opción "Herramientas para análisis"). Eso es imprescindible para que no te de error la función FIN.MES que incluyo dentro de la fórmula.

La fórmula en cuestión es esta (pon todo en una misma línea auque aquí se corte en varias), suponiendo que en A1 tengas una fecha del tipo 25/01/2008, o 28/12/2009, como ponías en tus ejemplos:

=REDONDEAR.MAS(MES(A1)/2;0) & SI(REDONDEAR.MAS(MES(A1)/2;0)-(MES(A1)/2)=0;DIA(FIN.MES(A1;-1))+DIA(A1);DIA(A1)) & " - " & EXTRAE(AÑO(A1);4;1)

Un saludo desde Barcelona (España)

Anónimo dijo...

Buenos dias Javier, como estas, espero que bien. La formula que me enviaste espectacular, no sabes cuanto trabajo me ahorro con ella. Solo tengo un pequeño inconveniente ¿cual es?: La fecha 03/01/07 (Ene 3 del 2007)solo me sale 13-7 Lo correcto es 103 - 7. El problema se presenta cuando toma el primer mes del bimestre y el dia es menor a 10.
Ejemplo 03/11/2009 La formula da 63 - 9 Lo correcto es 603 - 9. he tratado de corregir la formula pero nada no he podido, te pido encarecidamente el favor de ayudarme y perdona tanta molestia.
De antemano te doy las gracias, por toda la ayuda que me has brindado, que Dios te bendiga, te colme de bendiciones y te siga iluminando la mente con mas sabiduria para que le des ayuda a quien la necesite.
Atte, Eder Monterroza. Cartagena Colombia

Javier Marco dijo...

Es todo cuestión de usar la lógica. Lo que hago, es aislar cada componente de la fórmula (cada parte: día, bimestre, año, etc), y trabajo con cada uno de esos bloques. Luego lo uno todo, y listo, porque sino, sería un galimatías.

Prueba esta fórmula, que lo que hace es evaluar si ese día es menor que 10, para añadir un cero delante:

=REDONDEAR.MAS(MES(A1)/2;0) & SI(REDONDEAR.MAS(MES(A1)/2;0)-(MES(A1)/2)=0;DIA(FIN.MES(A1;-1))+DIA(A1);SI(DIA(A1)<10;"0" & DIA(A1);DIA(A1))) & " - " & EXTRAE(AÑO(A1);4;1)

Un saludo.

Anónimo dijo...

Javier, muchas gracias, estoy totalmente agradecido por toda la ayuda que me brindaste, De todo corazón te digo algo, si tienes la oportunidad de venir a Cartagena Colombia, Ojala tengamos la oportunidad de vernos para brindarte toda la atención que ud se merece. Inclusive te invito a la finca a comer carne asada.
Otra cosa, tengo poco tiempo de estar usando office, mas o menos como 6 meses, pero soy un asiduo hincha de excel, a tal punto que en el poco tiempo de estar manejandolo lo hago mejor que personas que llevan años en esto. ¿Como hago para aprender siquiera el 70% de lo que ud sabe.? Como hago los cursos donde me inscribo, o mandame ejercisios por este medio
Atte. Eder Monterroza Cartagena Colombia

Anónimo dijo...

Hola Javier, buenos Dias, te escribe, Eder Monterroza, Tengo bastante idea de programación en Visual Foxpro 7.0, inclusive ya he elaborado programas que en la actualidad los estan usando con unos resultados excelentes. La pregunta es: ¿Las tablas de Visaul Foxpro las puedo manipular con excel y como?. ¿Los formularios de los que ud habla para excel elaborados en Bisual Basic, se pueden elaborar en Visaul Foxpro y como? Te agradezco que me suministres esa información

Javier Marco dijo...

Muchas gracias por tu invitació, Eder.

Pues he de decirte que lo poco que sé, lo he ido aprendiedo a base de prueba-error, es decir, probando, investigando, y leyendo la ayuda del propio Excel (Tecla F1).

Javier Marco dijo...

imagino que podrás hacer cosillas con Visual Fox Pro y Excel, igual que con Access y Excel. En este mismo blog, tienes un ejemplo de como leer una base de datos Access desde Excel.

Seguramente para Visual Fro Pro, no debe ser muy diferente. Quizás lo único que cambie sea la cadena de conexión, aunque aquí tienes más información al respecto: http://www.connectionstrings.com/visual-foxpro

Anónimo dijo...

Hola Javier Buenas Tardes. Nuevamente te escribe eder, esta vez es para pedirte el favor que me ayudes con esto. En la formula que me mandaste para sacar un numero de una fecha, el año de la fecha sale con un solo digito y se requiere que salgan dos. Como hago?. Ejemplo. de 15-01-2005 sale 115 - 5. Lo correcto seria 115 - 05esta es la formula=REDONDEAR.MAS(MES(A1)/2;0) & SI(REDONDEAR.MAS(MES(A1)/2;0)-(MES(A1)/2)=0;DIA(FIN.MES(A1;-1))+DIA(A1);SI(DIA(A1)<10;"0" & DIA(A1);DIA(A1))) & " - " & EXTRAE(AÑO(A1);4;1)
Corrigemela por favor

J.Antonio dijo...

Hola Javier, busque respuesta a mis dudas hasta que te encontre, Gracias por tu ayuda. Ahora bien tengo una duda, tengo un caso que necesito saber los dias transcurridos entre fechas, aunque segui tus instrucciones no me dio el resultado ya que estoy comparando entre meses que en la fecha inicial es mayor y me saca dias diferentes, Ej. 19/12/2005 VS. 23/03/2010, necesito generar solo los dias desde el 19 de Dic. hasta el 23 de Mar.; el resultado que me da es de 33, pero si lo hago manual es de 94. Como lo puedo corregir? de antemano Gracias, y nuevamente Felicidades por tu pagina, es de gran ayuda!!

Javier Marco dijo...

Para Eeder:

Prueba esta fórmula:

=REDONDEAR.MAS(MES(D1)/2;0) & SI(REDONDEAR.MAS(MES(D1)/2;0)-(MES(D1)/2)=0;DIA(FIN.MES(D1;-1))+DIA(D1);SI(DIA(D1)<10;"0" & DIA(D1);DIA(D1))) & " - " & EXTRAE(AÑO(D1);3;2)

Si te fijas, cambia la parte del final, donde le estamos diciendo que cuando estemos con el año, que coja a partir del 3er carácter, y extraiga dos dígitos a partir de el (de ahí el 3 y el 2 del final).

Un saludo.

Javier Marco dijo...

Para J.Antonio, si en A1 tienes como fecha 19/12/2005 y en A2 tienes 23/03/2010, pon esta fórmula:

=SIFECHA(A1;A2;"yd")

Eso te arrojará como resultado: 94 días de diferencia, con independencia de los años que haya también de diferencia.

Un saludo.

Anónimo dijo...

Buenos dias Javier. Nuevamente Eder, Te agradezco todo lo que has hecho por mi. estoy totalmente agradecido. Muchas Gracias. De paso te pregunto algo. Por que en la ultima parte de la formula si la dejamos igual, es decir, EXTRAE(AÑO(A1);4;1)y en vez de uno le colocamos 2 que es el numero de los digitos del año que se van a extraer, ¿por que sigue extrayendo un solo digito.? Me doy cuenta que en la formula Ud cambia el 4 por 3 y el 1 por 2. por que explicame?. perdona tanta molestadera pero en mi tierra dicen que el que pregunta no herra

Javier Marco dijo...

Hola Eder.

Pues la explicación es sencilla. La función EXTRAE, lo que hace es eso, extraer un dato de otro dato. En este caso, le estamos diciendo que extraiga del año, 2 dígitos (de ahí el 2), a partir del 3er carácter (de ahí el 3).

Si pongo esto:

=EXTRAE(AÑO(A1);4;2)

Le estoy diciendo algo como esto: "extrae del año, y a partir del 4º carácter (el 4º caracter se incluye, es decir, se cuenta), dos caracteres". Como el año solo tiene 4 caracteres, a partir del 4º inclusive (porque se cuenta el 4º caracter), solo puede extraer 1, ya que el año solo contiene 4 dígitos.

Eso que pretendes funcionaría, si el año tuviera 5 caracteres (XXXXX), pues podríamos extraer 2 dígitos, contados a partir del 4º caracter.

Saludos.

J.Antonio dijo...

Javier, buenas tardes! Gracias por contestarme, solo para confirmarte, en lo que me contestas, exactamente es como yo lo estaba haciendo segun tu explicacion del blog, pero aunque lo haga nuevamente me sigue saliendo el mismo resultado (33); ya revise mi configuracion regional (dd/mm/yyyy) y la del excel y estan sincronizadas, la verdad no se que mas debo revisar :( ... De antemano Gracias por tu ayuda!

Javier Marco dijo...

J.Antonio, sinceramente no se donde puede estar el problema con esa diferencia de fechas, pues debería funcionarte correctamente.

Pruébalo en otra versión de Excel (algún amigo, algún compañero de trabajo, etc.). Es probable que esa función, como no está documentada en algunas versiones de Excel (por ejemplo, en la versión Excel 2003 no aparece en la propia ayuda, ni en el listado de funciones, aunque funciona correctamente, o al menos a mí me funciona correctamente en mi versión de Excel 2003), esté dando problemas. Prueba a actualizar los service packs (SP) de tu versión de Office, a ver si de esa forma se soluciona.

Más no te puedo decir. Un saludo.

Anónimo dijo...

Buenos dias Javier, te escribe Eduardo Contreras de Cartagena Colombia, Amigo de Eder al cual ya le has explicado formulas en Excel. Leyendo tu blog me encuentro que justo lo que le explicaste a Eder es lo que yo necesitaba ya que llevamos la numeracion del ganado de la misma forma. Pero quiero que me expliques cada uno de los pasos de la formula, es decir, que hace cada paso. A continuación te escribo las formulas. =REDONDEAR.MAS(MES(A1)/2;0) & SI(REDONDEAR.MAS(MES(A1)/2;0)-(MES(A1)/2)=0;DIA(FIN.MES(A1;-1))+DIA(A1);DIA(A1)) & " - " & EXTRAE(AÑO(A1);4;1)
Explicame paso a paso esta formula y en la funcion fin.mes utilizas un -1 por que y para que. de antemano te agradezco la atencion que le des a la presente

Javier Marco dijo...

Hola Eduardo. ¿No me digas que no entiendes nada de esa fórmula?. Algo tienes que entender, seguro.

Anónimo dijo...

Hola Javier, como estas,hace rato no te molesto y pregunta es la siguiente. Access es un Lenguaje de programación como Visualfoxpro?. Se pueden elaborar programas y luego compilarlos como en el VFP. Es que estoy interezado en aprender Access 2007. pero me dijeron que no es un lenguaje de programación y me dejaron indeciso.
Atentamente Eder Monterroza. Cartagena Colombia

Javier Marco dijo...

Access es una aplicación del paquete ofimáctico Office, y está pensado para gestionar gran cantidad de datos (es una base de datos). Eso sí, nada comparable con otras bases de datos (o motores de bases de datos), como SQL Server, o MySQL por ejemplo.

Con access se pueden llegar a desarrollar aplicaciones, y lo único que necesitarás será conocer algo de Visual Basic para Aplicaciones (VBA), que es algo así como una versión reducida de Visual Basic.

Victor dijo...

Hola, buenos días, necesito tu ayuda!!!

Lo que necesito es sumarle 1.25 días a cada mes que va pasando a partir de la fecha de ingreso del trabajador a la empresa, es decir si tengo una persona que ingresó el 01 de enero de 2009, quisiera saber si existe una fórmula que automáticamente al llegar al 01 de febrero de 2009 esta persona aparezca con 1.25 días de vacaciones en la celda siguiente, al llegar al 01 de marzo aparezca en la misma celda que ya tiene 2.50 días de vacaciones y así durante todo el año.

El motivo por el que necesito saber si hay una fórmula que pueda sumar ese “1.25” cada mes es porque tengo 500 empleados a los que les tengo que hacer el cálculo manual mensualmente y realmente es algo que me quita mucho tiempo y quisiera ver si hay alguna forma de poder hacerlo con una formula.

Javier Marco dijo...

Victor, con lo que has leído en este artículo, lo tendrías que tener chupado, pues aquí está toda la información que necesitas.

No obstante, te dejo la solución para que la descargues desde aquí, a través de un ejemplo: http://www.megaupload.com/?d=OZF75KTZ

Saludos.

Anónimo dijo...

Buenos dias Javier te saluda Eder Monterroza, mi pregunta es la siguiente. En Excel tengo un valor por decir algo 1.567.890 quiero que por medio de una formula me aparesca ese valor en letras, es decir, Un millon quinientos secenta y siete mil ochocientos noventa pesos. Te agradezco que me ayudes con esto.
Por otra parte quiero pedirte un concepto que es mejor aprender Biusal Basic, Sql, Mysql. Lo anterior con el fin de programar

Anónimo dijo...

Hola esta muy bueno se agradese y esperando simpre encontrar informacion tan util ----- Eduka

Anónimo dijo...

Estoy elaborando una tabla de excel para el calculo de la cuota principal, intereses, y mantenimiento de valor de la moneda, deseo saber que formula o funcion puedo utilizar para que el la tabla las cuotas por el numero de periodos a amortizarce el prestamo se presenten automaticamente basado en el tiempo del prestamos. gracias, espero comentarios o respuesta.

Javier Marco dijo...

Puedes obtener esa información, de un artículo donde hablamos precisamente de como calcular préstamos: Calcular préstamos e hipotecas.

Una vez hayas rellenado los datos del formulario, para simular el préstamo, se te generará una tabla donde podrás ver las fórmulas aplicadas.

Un saludo.

Anónimo dijo...

holaa¡¡ buen trabajo es precisamente lo que necesitaba, pero tengo una pregunta...como se haria para sumar el total de todos los tiempos transcurridos de todas las personas del ejemplo? es decir..el total de años, meses y dias de todos. Gracias y un saludo y fantástico trabajo

Javier Marco dijo...

Podrías sumar las columnas. Siguiendo ese ejemplo, te daría:

168 años, 38 meses, y 70 días.

Pero claro, como queremos dejar bonito eso, para que por ejemplo, cuando pasen de 30 días, se cuente un mes más (70 días = 2 meses y 10 días), entonces deberíamos hacer algo como esto (lo he hecho deprisa y corriendo, así que puede haber algún fallo, pero lo he probado con el ejemplo, y funciona):

Para los años:

=SUMA(C5:C10)+SI(SUMA(D5:D10)>12;ENTERO(SUMA(D5:D10)/12);0)

Para los meses:

=SI(SUMA(D5:D10)>12;SUMA(D5:D10)-(ENTERO(SUMA(D5:D10)/12)*12);SUMA(D5:D10))+SI(SUMA(E5:E10)>30;ENTERO(SUMA(E5:E10)/30);0)

Para los días:

=SI(SUMA(E5:E10)>30;SUMA(E5:E10)-(ENTERO(SUMA(E5:E10)/30)*30);SUMA(E5:E10))

Salu2

Anónimo dijo...

Hola Javier nececito ayuda en excel 2010. Te explico en la celda A2 puede estar culaquiera de estos textos. Desayuno, Almuerzo o Comida. La B2 va a tener el valor de la comida ($ 5.000) y la C2 una formula que le descuente el costo al valor de la comida. Ejemplo. Si A2 es desayuno le descuenta al valor de la comida, o sea, a B2 $ 1.500 quedando en C2 $ 3.500. Si A2es Almuerzo le descuenta $ 2.200 quedando en C2 $ 2.800 y si A2 es Comida le descuenta a B2 $ 2.600 quedando en C2 $ 2.400. Por favor te pido encarecidamente que me ayudes, trabajo en un restaurante y sabes el camello que me ahorro con esta formula.

Javier Marco dijo...

Prueba esta fórmula en C2:

=SI(A2="Desayuno";B2-1,5;SI(A2="Almuerzo";B2-2,2;SI(A2="Comida";B2-2,4;"Error")))

Ojo, en la fórmula igual tienes que cambiar los datos puestos manualmente, como por ejemplo el 1,5 (igual tienes que cambiar el coste). En España, el separador de miles es el punto, y el separador decimal es la coma. Creo que en tu caso es todo lo contrario (la coma es el separador de miles, y el punto el separador decimal).

Saludos.

Anónimo dijo...

Hola Javier buenos días, la formula que me enviaste para lo del restaurante funciona excelente, te doy mil y mil gracias. Es mucho el trabajo que me ahorro con ella. Gracias nuevamente

Anónimo dijo...

Buenas noches Javier, disculpa que te moleste otra vez, pero es que, la formula que me enviaste para aplicarla al Restaurante si funciona pero cuando el valor de las comidas son fijos y resulta que los valores no son fijos. Por ejemplo hay Desayunos de $ 2.000, $ 3.000, $ 4.000, $ 5.000, $ 6.000 y $ 7.000. El costo varia de acuerdo al precio así por ejem.
Desayuno de $ 2.000 Costo $ 800
Desayuno de $ 3.000 Costo $ 1.600
Desayuno de $ 4.000 Costo $ 2.200
Desayuno de $ 5.000 Costo $ 2.800 y así sucesivamente, en realidad que es lo que quiero, lo siguiente
Cuando A2 = Desayuno y B2 = $ 2.000en C2 debe aparecer $ 800.
Cuando A2 = Desayuno y B2 = $ 3.000en C2 debe aparecer $ 1.600. Es decir el precio de costo que queda reflejado en la celda C2 va a variar de acuerdo a A2 y B2. Recuerde que en A2 puede ser igual a Desayuno, Almuerzo o comida y B2 puede tener cualquier valor. Mire lo siguiente A2 = Desayuno y B2 = $ 5.000 C2 = $ 2.800. Pero si A2 = Almuerzo B2 = $ 5.000 ya C2 no seria igual a $ 2.800, por que A2es igual a Almuerzo y el costo de un desyuno de $ 5.000 no es el mismo de un almuerzo de $ 5.000 aunque tengan el mismo precio, en este caso el costo del almuerzo de $ 5.000 seria $ 3.200 asi que en C2debe aparecer el valor 3.200. en todo caso la formula debe preguntar si A2 es Desayuno, Almuerzo o Comida y por el valor que esta en B2 y de acuerdo a lo que este en las celdas sacar el resultado en C2. Creo que ahora si me hice entender y espero que me ayude, se lo pido encarecidamente.

Javier Marco dijo...

Descárgate el ejemplo que he colgado aquí (el libro contiene 2 hojas o pestañas):
http://www.megaupload.com/?d=2TO4WFJ4

Saludos

Anónimo dijo...

Excelente Don Javier, la formula funciona a la perfección, y en la forma que esta diseñada queda mas facil hacer los cambios de los valores y los costos para el año 2011. Mil y mil gracias, De todo corazón le deseo una Feliz Navidad y un Prospero y Feliz Año Nuevo.

Javier Marco dijo...

Muchas gracias :-)

Los mismos deseos para tí, y para el resto de lectores del blog.

lalo dijo...

Ayuda... Como puedo determinar el tiempo transcurrido entre fechas en excel? es decir, mi documento se firma el 01/01/2011 y tiene vencimiento a 15 dias para el dia 16/01/2011 se vence y es dia que no se me entrega como puedo determinar los dias que lleva transcurridos este documento despues del dia 16/01/2011? y hoy estamos a 26-01-211 ayudenme, Gracias...

Javier Marco dijo...

Lalo, imagina que en A1 tienes la fecha de vencimiento de ese documento (16/01/2011). Pon esto en A2:

=HOY()-A1

Luego, a esa celda (A2), le das formato numérico, y listo, te aparecerán los días excedidos con respecto a la fecha de hoy (la fecha en que abras ese fichero de excel).

Saludos.

lalo dijo...

Javier Marco, Agradezco bastante tu apoyo.
Saludos!

lalo dijo...

Javier, Buenas tardes.

Pregunta.
Qué formula, tengo que aplicar para que al momento de abrir mi fichero no siga continuando ya que, tengo como resultado la entrega.
ejem.

Firma de Notif. SATIC
21/12/2010
Dias Vencidos Satic
45
Entrega de Doctos. SATIC 02
4-Feb-11
Es decir cuando habra mi fichero quiero que no avance mas el 45.
Saludos...

Anónimo dijo...

Buenas noches Don Javier, mis mas sinceros saludos. Le escribe Eder Monterroza de Cartagena Colombia, necesito de su ayuda en excel 2010. En la celda A2 tengo el valor 100 y en la B2 tengo 200. En la celda C3 quiero sacar la sumatoria de A2+B2. Pero cuando las celdas A2 y B2 esten sin valores en C3 no debe salir el signo -. Le explico la formula que estoy utilizando en C3
=SI(A2="";"";SI(B2="";"";(A2+B2))Esta formula funciona pero cuando A2 y B2 tienen valores. Si le quito el valor a A2 la formula en C3 deja de funcionar, en ese caso debe mostrarme el 200 de B2 y lo mismo si dejo A2 y borro B2 la formula tampoco funciona. En todo caso lo que yo quiero es que si una de las dos tiene valor aparesca en C3 con la condicion de que si ambas estan en blanco la formula en C3 tambien aparesca en blanco y no el simbolo -. Por favor expliqueme en que estaba errado.

Javier Marco dijo...

Hola Eder. Eso te ocurre porque le estás dando a la celda donde tienes la suma, formato de Contabilidad. Si le das formato numérico, no te presentará el guioncito ese.

No obstante, si quieres solucionarlo con una fórmula, prueba esta:

=SI(Y(A2="";B2="");"";A2+B2)
Esa fórmula viene a decir: Si A2 y B2 están vacías (ambas a la vez, de ahí el Y), entonces deja la celda vacía, y en caso contrario, haz la suma.

Anónimo dijo...

Muchicimas gracias Don Javier, Problema solucionado no conocía la funcion Y. Dígame por donde puedo estudiar las funciones de Excel 2010
Mil y Mil gracias. Eder

Javier Marco dijo...

Pues desconozco dónde puedes obtener información sobre todas las funciones de excel, pero se me ocurre que no hya nada mejor que la ayuda del propio Excel (F1).

Un saludo.

Anónimo dijo...

Hola, excelente ejemplificación, me fué de gran utilidad.

Ojalá y nos sigas compartiendo información.

grax

Anónimo dijo...

Don Javier, muy buenas tardes le escribe Eder de Cartagena Colombia. La pregunta es la siguiente. Tengo un archivo en Excel 2010. Con las siguientes columnas: Cédula, Nombre, Dirección, Teléfono y Categoría. Son en total 588 registros, quiero por medio de una formula extraerlos por categorias y crear una hoja nueva por cada una de ellas, las categorias son: Uno, Dos, Tres, Hasta la Cinco. Me explico, en este archivo la categoria Tres tiene 121 registros la formula debe crear una hoja para esos 121 registros y así sucesivamente para cada categoria, es decir deben crearse cinco hojas nuevas, una por cada categoria. Ojo. el archivo principal debe quedar igualito y cada registro que se adicione en él, debe adicionarse a la hoja de la categoría que corresponda. Por favor si me puede ayudar con esto se lo agradeceria ya que me ahorro tiempo y trabajo

Javier Marco dijo...

Pues tendrás que adaptar una idea ya hecha. En este artículo: estreno del blog, mírate la pregunta del usuario hecha el 23 de marzo del 2010, y mi respuesta.

Solo tendrás que adaptarla a tu caso particular.

Saludos.

Anónimo dijo...

Buenas tardes don Javier, Le escribe Eder, para acomodarla respuesta que Ud me da hay que tener conocimientos sobre Visaul Basic cosa que no tengo, pero me voy a valer de un amigo para que me ayude ya le estare contando como nos ha ido. Pregunto el lenguaje es Visaul Basic si o no

Javier Marco dijo...

Visual Basic para Aplicaciones (VBA), que es una versión reducida de Visual Basic.

Saludos.

Anónimo dijo...

Buenas tardes Don Javier, le escribe Eder, le cuento que adapte la respuesta que publicó el 23 de marzo del 2010 en estreno del blog y me fue excelente. Ahora la pregunta es la siguiente. En Excel 2010 en la celda A1 escribo la fecha, 27/02/2011. Al personalizar la celda para que muestre feb - 27 - 2011. La primera letra del mes quiero que salga en mayuscula y no en minuscula como por defecto la pone, es decir, que muestre Feb - 27 - 2011. En las versiones anteriores no ocurria ese problema ya que estas por defecto colocaban la primera letra del mes en mayuscula. Espero que me colabore con este pequeño impase

Anónimo dijo...

Hola Javier, si tengo un listado de cien facturas que suman un millon de euros, pero un cliente me paga 30.000 euros y necesito cuadrar ese valor entre los diferentes valores de las cien facturas, existe alguna forma?

Anónimo dijo...

Hola! Si tengo unas horas por celdas (columnas) en horizontal en excel así:

23 45 13 28 35 40 40 30 35

Cómo puedo hacer en una columna que para cada 115 es 1.25 ?

Esto es que estoy entrando las horas de los empleados por semana y para cada vez que hacen 115 horas al mes , acumulan 1.25 día de vacaciones. Les agradeceré la ayuda infinitamente. Saludos

Anónimo dijo...

Buenas dias Don Javier, le escribe Eder, le cuento que adapte la respuesta que publicó el 23 de marzo del 2010 en estreno del blog y me fue excelente. Ahora la pregunta es la siguiente. En Excel 2010 en la celda A1 escribo la fecha, 27/02/2011. Al personalizar la celda para que muestre feb - 27 - 2011. La primera letra del mes quiero que salga en mayuscula y no en minuscula como por defecto la pone, es decir, que muestre Feb - 27 - 2011. En las versiones anteriores no ocurria ese problema ya que estas por defecto colocaban la primera letra del mes en mayuscula. Espero que me colabore con este impase. Me sorprende que tenga preguntas en el blog sin contestar

Anónimo dijo...

TIENEN EL ARCHIVO YA CREADO? PUEDEN SUBIRLO?

Javier Marco dijo...

Acabo de subirlo. Al final del artículo encontrarás el enlace.

Un saludo.

Anónimo dijo...

Buenas nonches Don Javier. Reciba de mi parte un cordial saludo. Veo que hace rato no contesta por aqui. Mi pregunta es la siguiente. Tengo Excel 2010. tengo un libro con dos hojas en la hoja 2 estan los datos de los clientes. En La columna A estan los codigos y en la B los nombres. Quiero que en la hoja 1 por medio de validacion de datos, Lista, me muestre estas dos columnas o sea la A y la B de la hoja dos. ¿Esto se puede? y si se puede como se hace?. Por favor colaboreme con esto. Lo he intentado hacer, pero nada no doy con esto.De antemano le agradezco de todo corazon la ayuda que me de.

Atte

Rumaldo Gracia

Javier Marco dijo...

En principio, las listas de validación solo permiten 1 columna de datos, o 1 fila. No obstante, quizás te sirva esta solución, para buscar un artículo, su precio, y su referencia, a partir de una tabla de datos, y utilizando una lista de validación:

http://www.megaupload.com/?d=MOMNJKL2

Saludos.

Anónimo dijo...

Buenos dias Javier, te saluda Rumaldo. Quiero agradecerte por tu valiosa colaboracion, no te imaginas el trabajo que ahorro con esa formula que Dios te bendiga.

Anónimo dijo...

Buenas noches don Javier, le saluda Eder Monerroza de cartagena Colombia. Mi pregunta es la siguiente. ¿Existe alguna forma de corregir las listas personalizadas de excel 2010?. Lo que sucede es que la lista de los meses esta escrita en minusculas y logico al utilizarlas en fechas personalizadas sale ene 01 2011. Lo correcto seria Ene 01 2011. Lo mismo sucede con los dias de la semana. Que puedo hacer para corregir esto.

Javier Marco dijo...

Puedes personalizar los formatos. Para ello, simplemente ponle este formtato a la celda:

[$-340A]mmm dd aaa

Obtendrás: Ene 01 2011

Y con este otro:

[$-340A]dddd

Obtendrás: Sábado

Porque el 1 de enero de 2011 es sábado.

Saludos.

Anónimo dijo...

Buenas noches don Javier, nuevamente Eder el formato que me envió para colocar la primera letra del mes o del día de la semana en Mayúscula en Excel 2010 no funciona. Ud. me envió el siguiente formato [$-340A]mmm dd yyyy. Esto arroja ene 01 2011 y lo correcto sería Ene 01 2011. El formato que Ud me envió lo estoy colocando en el formato personalizado de fecha. por favor corrija me, donde tengo el error. De antemano le pido disculpas por tanta molestia y Miles y miles de gracia por la ayuda que me preste.
Eder de Cartagena Colombia

Javier Marco dijo...

Hola Eder. Siento no poder ayudarte más, pues desconozco por qué no funciona en Excel 2010. En la versión de Excel 2003, que es donde la estaba probando, funciona correctamente. Efectivamente en Excel 2010, no funciona (lo acabo de comprobar).

Anónimo dijo...

Buuu!! se me ahce muy buena la fórmula, sin mebargo ami me bota #¡NUM! al final y no sé si sea por el formato, también tengo la duda para el caso de utilziar la formula junta que formato de celda lleva?

Javier Marco dijo...

Te aparece lo de #¡NUM! porque has invertido las fechas. En este ejemplo: =SIFECHA(B5;C$2;"y") la celda B5 debe contener una fecha anterior o más antigua que la de la celda C2. Seguramente en tu caso las has puesto al revés las fechas en esas celdas.

Saludos.

Anónimo dijo...

Nop ya lo cheque y no es eso tengo entendido la parte de poner primero la fecha más actual sin embargo creo que es algo respecto del frmato de celda... :(

Anónimo dijo...

Hola javier, de gran utilidad tus clases! escribí toda mi antiguedad docente, y calculé el tiempo trabajado entre 2 fechas: 0 años 0 meses 12 días, 12 años 5 meses 9 días, etc. Puedo sumar toda la columna con ese formato? o tengo que hacer una para años, otra para meses y otra para días y luego sumar por separado?

Javier Marco dijo...

Simplemete suma la columna de años, la de meses, y la de días. Luego en la columna auxiliar donde unes esos tres datos (años, meses, y días), aplicas la misma fórmula, y ya lo tendrás solucionado.

Anónimo dijo...

HOLAA COMO PUEDO UTILIZAR LA FUNCION =SIFECHA NO ME SALE NINGUN RESULTADO

Anónimo dijo...

Buenas noches Don Javier.

Leyendo su prestigios blog he aprendido muchas cosas. Gracias por las formulas escritas en esta herramientas. de paso quisiera hacerle esta pregunta.

Expliqueme como anido funciones dentro de la funcion SUMAPRODUCTO.

De antemano le doy las gracias por su colaboracion.

Javier Marco dijo...

Hola que tal. Puedes echarle un vistazo a la función SUMAPRODUCTO en este artículo: medias ponderadas y en este otro: buscar valores en un rango de datos.

Saludos.

Julio Arriola H. dijo...

Excelente, clarisima tu respuesta, se nota que quieres que los demas aprendan, te felicito por tu buena voluntad, haré lo mismo por otros cuando esté en mis manos el ayudar en algo que domino.

Anónimo dijo...

Lo primero, feliz año 2012.
Yo me vuelvo loco con esta fórmula, me salen mal los días, a veces, me explico.
Fecha inicial para calcular 30/06/2011 que es la celda A4, fecha final Hoy
Esta es mi fórmula
=SIFECHA(A4;HOY();"y")&"Año(s), "&SIFECHA(A4;HOY();"ym")&"Mes(es) y "&SIFECHA(A4;HOY();"md")&"Día(s)"
Si pongo en la fecha inicial 1,2,3 ó 4/07/11 me sale bien, pero al ser números posteriores a hoy (5,6,7,30...) me calcula mal los días (meses y años bien).
Un saludo y haber quién da con la tecla, jeje.

Javier Marco dijo...

A mi me funciona correctamente.

Si pongo 03/07/2011, me devuelve esto, teniendo en cuenta que hoy es 4 de enero: 0Año(s), 6Mes(es) y 1Día(s)

Si pongo 07/07/2011, me devuelve: 0Año(s), 5Mes(es) y 28Día(s)

Si pongo 18/07/2011, me devuelve: 0Año(s), 5Mes(es) y 17Día(s)

Saludos.

Anónimo dijo...

Muchas gracias, Javier, pero a mí el día 18/07 me da 5 meses y 118 días, el día 07/07 5 meses y 142 días, el día 3/7 sí me da igual que a tí; la fórmula es la misma?

Serán los duendes de la informática porque yo me vuelvo loco y no pillo el fallo.

Gracias.

Javier Marco dijo...

He utilizado tu misma fórmula. Y lo he probado en Excel 2003 y en Excel 2010. En ambas versiones obtengo el mismo resultado.

Si tienes la oportunidad de probarlo en otra instalación de Excel (otra máquina), prueba a ver.

Saludo.

felix mansilla dijo...

Javier..muxasss. gracias....gente como tu engradece este planeta ya que ayudas a desconocidos

Anónimo dijo...

Hola Javier, muy buenos dias le saluda Eder Monterroza de Cartagena Colombia. Mi pregunta es la siguiente. En dias pasados vi un archivo en Excel 2010,La columna A tenia formato Fecha y cada vez que el cursor se posesionaba en una celda de la columna A en la parte superior derecha de la celda(Donde se pone la marca de comentario) se ponia un cuadrito que al hacerle clik desplegaba un calendario, donde se elegía una fecha con clik y esta se colocaba en la celda seleccionada. Como en las tablas de Acces cuando el campo es numerico. Mi pregunta es esto se logra con macro o existe alguna funcion para esto y si es con funcion por favor expliqueme como es la formula. De antemano muchas gracias por la atencion prestada al presente

Javier Marco dijo...

Aquí tienes algo muy parecido: calendario emergente en Excel.

Saludos.

Anónimo dijo...

Don Javier, Miles y Miles de gracias por su ayuda, que el todo poderoso derrame sobre ud. salud, prosperidad, felicidad y dinero
Eder

Anónimo dijo...

Excelente Blogs FELICIDADES Marcos

Anónimo dijo...

Buenas noches don Javier, le saluda Eder Monterroza de Cartagena colombia. En la pregunta que le hice por este medio, el día 7 de diciembre del 2010, Donde le pedia ayuda para llevar el control de un restaurante, la cual ud muy generosamente me respondio enviandome un archivo por este enlace
http://www.megaupload.com/?d=2TO4WFJ4
En el cual estaba la respuesta exacta que yo necesitaba y con la cual se venia trabajando hasta el dia 4 de septiembre del 2012. Le cuento algo insolito. Resulta que se metieron al restaurante nos robaron todos los equipos incluyendo el Disco Duro de un portatil donde haciamos copia de seguridad y las memorias usb que teniamos, nos dejaron fue limpios de información. Ya gracias a Dios tenemos otro equipo y vamos a implementar el archivo que usted nos envio por el el enlace arriba descrito pero con tan mala suerte que la pagina http://www.megaupload.com ya no existe o no abre. Será que ud por casualidad tiene ese archivo para que me haga el favor de envuiarmelo nuevamente. He intentado hacer la formula pero no he sido capaz, se que la hizo con una función que se llama SUMAPRODUCTO, pero nada no doy con la formula. Le agradezco de todo corazón cualquier ayuda que me pueda prestar.